In Folge 12 und 13 seiner Serie zur räumlichen Geometrie [1] stellt Christoph Pöppe Polyeder vor, die sich aus sich gegenseitig durchdringenden platonischen Körpern zusammensetzen. Hier will ich ergänzend ein paar Hinweise zur Umsetzung mit dem Programm POV-Ray geben.
Die Vorgehensweise ist stets gleich: Die Kopien des Ausgangspolyeders, der sich im Zentrum des POV-Ray- Koordinatensystems befindet, werden jeweils unterschiedlich gedreht und bilden so den Durchdringungskörper.
Dieser Polyeder ist auf M. C. Eschers bekannter Lithographie
Wasserfall [2] zu sehen.
Einbeschrieben sind die drei Hexaeder in einen Oktaeder. Die acht Ecken eines Hexaeders berühren die acht Kanten des Oktaeders.
union {
object {Hexaeder rotate x*45}
object {Hexaeder rotate y*45}
object {Hexaeder rotate z*45}
}
Um die vier Raumdiagonalen eines Hexaeders, diese sind
dreizählig, wird jeweils ein Hexaeder um 60 Grad gedreht.
Um beliebige Achsen drehen, das geht in POV-Ray leider nicht. Die Transformation T1 (bzw. T2 etc.) dreht den Würfel so, dass eine seiner Raumdiagonalen auf der z-Achse liegt. Nachdem der Würfel um 60° um die z-Achse gedreht wurde, wird T1 (T2 etc.) umgekehrt (Drehungen in umgekehrter Reihenfolge mit umgekehrten Vorzeichen).
#declare T1 = transform {rotate < 45, degrees(atan(1/sqrt(2))), 0>};
#declare T2 = transform {rotate < 45,-degrees(atan(1/sqrt(2))), 0>};
#declare T3 = transform {rotate <-45, degrees(atan(1/sqrt(2))), 0>};
#declare T4 = transform {rotate <-45,-degrees(atan(1/sqrt(2))), 0>};
union {
object {Hexaeder transform{T1} rotate z*60 transform{T1 inverse}}
object {Hexaeder transform{T2} rotate z*60 transform{T2 inverse}}
object {Hexaeder transform{T3} rotate z*60 transform{T3 inverse}}
object {Hexaeder transform{T4} rotate z*60 transform{T4 inverse}}
}
Dem Dodekaeder ist ein Würfel so einbeschrieben, dass jeweils
fünf Dodekaederkanten ein Walmdach über eine der Würfelflächen
bilden. Folgt man dem Leitspruch »Jede Kante ein First«, passen
insgesamt fünf Würfel in den Dodekaeder.
Im untenstehenden POV-Ray-SDL-Schnipsel ist W die halbe Breite und H die Höhe des Walmdachs. Sie bestimmen den Winkel in dem der Würfel, und somit der gedachte Dodekaeder, gekippt werden. Zwei der Dodekaederflächen befinden sich nun parallel zur x-z-Ebene und man braucht die Würfelkopien nur noch um die y-Achse zu drehen.
#declare W = cos(radians(36));
#declare H = sqrt(pow(cos(radians(18)), 2) - pow(W, 2));
#declare T = transform {rotate x * degrees(atan(H / W))}
union {
object {Hexaeder transform{T}}
object {Hexaeder transform{T} rotate y* 72}
object {Hexaeder transform{T} rotate y* 144}
object {Hexaeder transform{T} rotate y*-144}
object {Hexaeder transform{T} rotate y* -72}
}
Den Würfel des Fünffachhexaeders braucht man nur durch einen
dem Würfel einbeschriebenen Tetraeder zu ersetzen. Jeweils eine
der zwei Diagonalen pro Würfelfläche bildet eine Kante des
Tetraeders.
Vier Ecken des Würfels sind noch frei, es passt also noch ein zweiter Tetraeder in den Würfel, und somit noch fünf weitere in den Dodekaeder.
Ein Oktaeder kann dem Würfel so einbeschrieben werden, dass
seine Ecken auf die Mittelpunkte der Würfelflächen treffen. Die
Eckpunkte des Oktaeders liegen also auf den Achsen des
Koordinatensystems (Ein so positionierter Oktaeder wird auch für
die beiden nächsten Durchdringungskörper vorausgesetzt).
Durch eine 45-Grad-Drehung um die y-Achse berührt der Ausgangsoktaeder den Würfel nur noch oben und unten. Und dann gibt es da noch die x- und die z-Achse.
Eine standfestere Version des Dreifachoktaeders ist auf der oben erwähnten Escher-Grafik zu sehen. Hierfür werden die Oktaeder in Richtung Rotationsachse mit 1/sqrt(2) skaliert.
Auch diese beiden Mehrfachoktaeder funktionieren jeweils wie der
entsprechende Mehrfachhexaeder. Also einfach im POV-Ray-Skript
Hexaeder gegen Oktaeder austauschen!
Ergänzend sei angemerkt, dass der Oktaeder einem Dodekaeder so einbeschrieben werden kann, dass seine Ecken auf den Mittelpunkten der Dodekaederkanten liegen.
Hexaeder, Tetraeder und Oktaeder mit POV-Ray
[1] www.wissenschaft-online.de/...
[2] btmdx1.mat.uni-bayreuth.de/~rockstroh/esch_wass.htm
site2004.de/durchdr.html